aboutsummaryrefslogtreecommitdiffstats
path: root/contrib/libgmp/mpn/sparc64/add_n.s
blob: 01d1f49564b348db9f40d742f7537662f67a279b (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
! SPARC v9 __mpn_add_n -- Add two limb vectors of the same length > 0 and store
! sum in a third limb vector.

! Copyright (C) 1995, 1996 Free Software Foundation, Inc.

! This file is part of the GNU MP Library.

! The GNU MP Library is free software; you can redistribute it and/or modify
! it under the terms of the GNU Library General Public License as published by
! the Free Software Foundation; either version 2 of the License, or (at your
! option) any later version.

! The GNU MP Library is distributed in the hope that it will be useful, but
! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
! License for more details.

! You should have received a copy of the GNU Library General Public License
! along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
! the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
! MA 02111-1307, USA.


! INPUT PARAMETERS
! res_ptr	%o0
! s1_ptr	%o1
! s2_ptr	%o2
! size		%o3

.section	".text"
	.align 4
	.global __mpn_add_n
	.type	 __mpn_add_n,#function
	.proc	04
__mpn_add_n:
	sub %g0,%o3,%g3
	sllx %o3,3,%g1
	add %o1,%g1,%o1			! make s1_ptr point at end
	add %o2,%g1,%o2			! make s2_ptr point at end
	add %o0,%g1,%o0			! make res_ptr point at end
	mov 0,%o4			! clear carry variable
	sllx %g3,3,%o5			! compute initial address index

.Loop:	ldx [%o2+%o5],%g1		! load s2 limb
	add %g3,1,%g3			! increment loop count
	ldx [%o1+%o5],%g2		! load s1 limb
	addcc %g1,%o4,%g1		! add s2 limb and carry variable
	movcc %xcc,0,%o4		! if carry-out, o4 was 1; clear it
	addcc %g1,%g2,%g1		! add s1 limb to sum
	stx %g1,[%o0+%o5]		! store result
	add %o5,8,%o5			! increment address index
	brnz,pt %g3,.Loop
	movcs %xcc,1,%o4		! if s1 add gave carry, record it

	retl
	mov %o4,%o0
.LLfe1:
	.size	 __mpn_add_n,.LLfe1-__mpn_add_n