aboutsummaryrefslogtreecommitdiffstats
path: root/MdePkg/Library/BaseIoLibIntrinsic/Arm/ArmVirtMmio.asm
blob: 93fe59b3cd46798e377a6347a0a72be5169c3a53 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
;
;  Copyright (c) 2014-2018, Linaro Limited. All rights reserved.
;
;  SPDX-License-Identifier: BSD-2-Clause-Patent
;


AREA IoLibMmio, CODE, READONLY

EXPORT MmioRead8Internal
EXPORT MmioWrite8Internal
EXPORT MmioRead16Internal
EXPORT MmioWrite16Internal
EXPORT MmioRead32Internal
EXPORT MmioWrite32Internal
EXPORT MmioRead64Internal
EXPORT MmioWrite64Internal

;
;  Reads an 8-bit MMIO register.
;
;  Reads the 8-bit MMIO register specified by Address. The 8-bit read value is
;  returned. This function must guarantee that all MMIO read and write
;  operations are serialized.
;
;  @param  Address The MMIO register to read.
;
;  @return The value read.
;
MmioRead8Internal
  ldrb    r0, [r0]
  dmb
  bx      lr

;
;  Writes an 8-bit MMIO register.
;
;  Writes the 8-bit MMIO register specified by Address with the value specified
;  by Value and returns Value. This function must guarantee that all MMIO read
;  and write operations are serialized.
;
;  @param  Address The MMIO register to write.
;  @param  Value   The value to write to the MMIO register.
;
MmioWrite8Internal
  dmb     st
  strb    r1, [r0]
  bx      lr

;
;  Reads a 16-bit MMIO register.
;
;  Reads the 16-bit MMIO register specified by Address. The 16-bit read value is
;  returned. This function must guarantee that all MMIO read and write
;  operations are serialized.
;
;  @param  Address The MMIO register to read.
;
;  @return The value read.
;
MmioRead16Internal
  ldrh    r0, [r0]
  dmb
  bx      lr

;
;  Writes a 16-bit MMIO register.
;
;  Writes the 16-bit MMIO register specified by Address with the value specified
;  by Value and returns Value. This function must guarantee that all MMIO read
;  and write operations are serialized.
;
;  @param  Address The MMIO register to write.
;  @param  Value   The value to write to the MMIO register.
;
MmioWrite16Internal
  dmb     st
  strh    r1, [r0]
  bx      lr

;
;  Reads a 32-bit MMIO register.
;
;  Reads the 32-bit MMIO register specified by Address. The 32-bit read value is
;  returned. This function must guarantee that all MMIO read and write
;  operations are serialized.
;
;  @param  Address The MMIO register to read.
;
;  @return The value read.
;
MmioRead32Internal
  ldr     r0, [r0]
  dmb
  bx      lr

;
;  Writes a 32-bit MMIO register.
;
;  Writes the 32-bit MMIO register specified by Address with the value specified
;  by Value and returns Value. This function must guarantee that all MMIO read
;  and write operations are serialized.
;
;  @param  Address The MMIO register to write.
;  @param  Value   The value to write to the MMIO register.
;
MmioWrite32Internal
  dmb     st
  str     r1, [r0]
  bx      lr

;
;  Reads a 64-bit MMIO register.
;
;  Reads the 64-bit MMIO register specified by Address. The 64-bit read value is
;  returned. This function must guarantee that all MMIO read and write
;  operations are serialized.
;
;  @param  Address The MMIO register to read.
;
;  @return The value read.
;
MmioRead64Internal
  ldr     r1, [r0, #4]
  ldr     r0, [r0]
  dmb
  bx      lr

;
;  Writes a 64-bit MMIO register.
;
;  Writes the 64-bit MMIO register specified by Address with the value specified
;  by Value and returns Value. This function must guarantee that all MMIO read
;  and write operations are serialized.
;
;  @param  Address The MMIO register to write.
;  @param  Value   The value to write to the MMIO register.
;
MmioWrite64Internal
  dmb     st
  str     r2, [r0]
  str     r3, [r0, #4]
  bx      lr

  END